你的位置: iPc 首页 > 全部文章 > 编程技术 > 阅读文章
科学X网    Office    苹果中国    微软中国    VPS

操作VB中的无边框窗体(移动,调整大小)

17
四月

在VB中,BorderStyle属性为0的窗体没有边框,并且也没有与边框相关的元素。这种窗体具有简洁、占用空间少等优点,用它可以设计出某些富有个性的窗体。但是,由于它没有标题栏,窗体不能移动,同时也不能改变大小,在某些情况下会给使用者造成一定的麻烦。本文介绍在VB中如何用API函数操作无边框窗体。
移动窗体

新建一标准工程,设置Form1的BorderStyle属性为0。此时运行程序后,无法移动窗体。为能移动窗体,在Form1的代码窗口声明下列函数和常数:
[codes=vb]Option Explicit

Private Declare Function ReleaseCapture Lib “user32” () As Long
Private Declare Function SendMessage Lib “user32” Alias “SendMessageA” (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long

Const WM_SYSCOMMAND = &H112
Const SC_MOVE = &HF012

在Form_MouseDown事件中输入以下代码:
Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)

‘按下鼠标左键
If Button = vbLeftButton Then

‘为当前的应用程序释放鼠标捕获
ReleaseCapture

‘移动窗体
SendMessage Me.hwnd, WM_SYSCOMMAND, SC_MOVE, 0

End If
End Sub

注意:此时窗体上不能放置除Shape控件以外的任何控件,否则,在被控件遮住的地方点按鼠标还是无法移动窗体。要使点按控件也能移动窗体,需再添加一个该控件的MouseDown事件过程,代码与上述过程代码相似。
改变窗体的大小

为了改变窗体的大小,需要添加一个Timer控件,以定时捕获鼠标在窗体中的位置。当鼠标位于窗体边缘时,改变鼠标的形状,以通知用户可以进行改变大小的操作。为此,将Timer控件的Interval属性设为100(即每过100毫秒检测一下鼠标位置),其他取默认值。
在Form1的代码窗口中再添加下列两个函数,并定义两个自定义变量和一个字符串变量:

‘取得窗体位置的函数
Private Declare Function GetWindowRect Lib “user32” (ByVal hwnd As Long, lpRect As RECT) As Long

‘取得鼠标位置的函数
Private Declare Function GetCursorPos Lib “user32” (lpPoint As POINTAPI) As Long

‘鼠标位置变量
Private Type POINTAPI

x As Long
y As Long

End Type
‘窗体位置变量

Private Type RECT
Left As Long

Top As Long
Right As Long

Bottom As Long
End Type

‘所要执行的动作变量,是移动还是改变大小及从哪个方向改变大小
Dim Action As String

在Timer1控件的Timer事件过程中添加以下代码:
Private Sub Timer1_Timer()

Dim MyRect As RECT
Dim MyPoint As POINTAPI

‘ MyRect返回当前窗口位置
Call GetWindowRect(Me.hwnd, MyRect)

‘ MyPoint返回当前鼠标位置
Call GetCursorPos(MyPoint)

Select Case True
‘鼠标位于窗体左上方

Case MyPoint.x < MyRect.Left + 5 And MyPoint.y < MyRect.Top + 5
Screen.MousePointer = vbSizeNWSE

Action = “LeftUp”
‘鼠标位于窗体右下方

Case MyPoint.x > MyRect.Right - 5 And MyPoint.y > MyRect.Bottom - 5
Screen.MousePointer = vbSizeNWSE

Action = “RightDown”
‘鼠标位于窗体右上方

Case MyPoint.x > MyRect.Right - 5 And MyPoint.y < MyRect.Top + 5
’45度双向鼠标指针

Screen.MousePointer = vbSizeNESW
Action = “RightUp”

‘鼠标位于窗体左下方
Case MyPoint.x < MyRect.Left + 5 And MyPoint.y > MyRect.Bottom - 5

Screen.MousePointer = vbSizeNESW
Action = “LeftDown”

‘鼠标位于窗体左边
Case MyPoint.x < MyRect.Left + 5‘水平双向鼠标指针
Screen.MousePointer = vbSizeWE

Action = “Left”
‘鼠标位于窗体右边

Case MyPoint.x > MyRect.Right - 5
Screen.MousePointer = vbSizeWE

Action = “Right”
‘鼠标位于窗体上方

Case MyPoint.y < MyRect.Top + 5
‘垂直双向鼠标指针

Screen.MousePointer = vbSizeNS
Action = “Up”

‘鼠标位于窗体下方
Case MyPoint.y > MyRect.Bottom - 5

Screen.MousePointer = vbSizeNS
Action = “Down”

‘鼠标位于窗体其他位置
Case Else

‘默认鼠标指针
Screen.MousePointer = 0

Action = “Move”
End Select

End Sub
当利用SendMessage函数由系统向窗口发送改变大小的信息时,只要将上面移动窗体的语句“SendMessage Me.hwnd, WM_SYSCOMMAND, SC_MOVE, 0”中的第3个参数改为相应的常数即可。

VB中&HF001~&HF008分别是从左、右、上、左上、右上、下、左下、右下8个方向改变窗体大小的常数。结合移动窗体的代码,将上述Form_MouseDown事件的代码综合如下(也可以把这8个常数声明为自定义常数):
Private Sub Form_MouseDown(Button As Integer, Shift As Integer, x As Single, y As Single)

‘按下鼠标左键
If Button = vbLeftButton Then

‘为当前的应用程序释放鼠标捕获
ReleaseCapture

Select Case Action
Case “Left”

SendMessage Me.hwnd, WM_SYSCOMMAND, &HF001, 0
Case “Right”

SendMessage Me.hwnd, WM_SYSCOMMAND, &HF002, 0
Case “Up”

SendMessage Me.hwnd, WM_SYSCOMMAND, &HF003, 0
Case “LeftUp”

SendMessage Me.hwnd, WM_SYSCOMMAND, &HF004, 0
Case “RightUp”

SendMessage Me.hwnd, WM_SYSCOMMAND, &HF005, 0
Case “Down”

SendMessage Me.hwnd, WM_SYSCOMMAND, &HF006, 0
Case “LeftDown”

SendMessage Me.hwnd, WM_SYSCOMMAND, &HF007, 0
Case “RightDown”

SendMessage Me.hwnd, WM_SYSCOMMAND, &HF008, 0
Case “Move”

SendMessage Me.hwnd, WM_SYSCOMMAND, SC_MOVE, 0
End Select

End If
End Sub [/codes]

关于本文
  • 属于分类:编程技术
  • 本文标签:,
  • 文章编辑:
  • 流行热度:正在感受现场气氛...
  • 生产日期:2007年04月17日 - 21时48分00秒
各种回音
  1. 说: 回复他/她

    哈哈,不错,帮助很大

微博评论箱